42 lines
1.4 KiB
Batchfile
42 lines
1.4 KiB
Batchfile
@echo off
|
|
if not defined GYXX_PYTHON set "GYXX_PYTHON=python"
|
|
REM Monthly creator report: run on 1st of each month at 08:30
|
|
REM 1. Read cmt_cooperations + cmt_creators + cmt_styles from PG
|
|
REM 2. Generate 9-section analysis report (Markdown)
|
|
REM 3. Create Feishu doc + save to cmt_creator_report
|
|
REM Register: schtasks /Create /SC MONTHLY /D 1 /TN YingxiaoYunying_MonthlyCreatorReport /TR %PROJECT_DIR%\data\tools\monthly_creator_report.bat /ST 08:30 /F
|
|
|
|
setlocal
|
|
|
|
for %%I in ("%~dp0..\..") do set "PROJECT_DIR=%%~fI"
|
|
if not defined GYXX_DATA_ROOT (
|
|
if not defined GYXX_PROJECT_ROOT (
|
|
echo ERROR: GYXX_DATA_ROOT or GYXX_PROJECT_ROOT must be defined. 1>&2
|
|
exit /b 3
|
|
)
|
|
set "GYXX_DATA_ROOT=%GYXX_PROJECT_ROOT%\var"
|
|
)
|
|
set LOG_DIR=%GYXX_DATA_ROOT%\logs\content_marketing\scheduled
|
|
set PYTHON=%GYXX_PYTHON%
|
|
where %PYTHON% >nul 2>&1 || set PYTHON=python
|
|
|
|
if not exist "%LOG_DIR%" mkdir "%LOG_DIR%"
|
|
|
|
set TS=%date:~0,4%%date:~5,2%%date:~8,2%_%time:~0,2%%time:~3,2%%time:~6,2%
|
|
set TS=%TS: =0%
|
|
|
|
set LOG_FILE=%LOG_DIR%\monthly_creator_report_%TS%.log
|
|
|
|
echo === Monthly creator report started at %date% %time% === > "%LOG_FILE%"
|
|
echo PROJECT_DIR=%PROJECT_DIR% >> "%LOG_FILE%"
|
|
|
|
cd /d "%PROJECT_DIR%"
|
|
|
|
call %PYTHON% -u -X utf8 data/tools/generate_creator_report.py >> "%LOG_FILE%" 2>&1
|
|
set RC=%ERRORLEVEL%
|
|
echo monthly_creator_report exit=%RC% >> "%LOG_FILE%"
|
|
|
|
echo === Monthly creator report finished at %date% %time% (rc=%RC%) === >> "%LOG_FILE%"
|
|
|
|
endlocal
|